EtherToken

// Submitted by EthereumHistory (ethereumhistory.com)
contract EtherToken {
    mapping (address => uint256) balances;
    mapping (address => mapping (address => uint256)) allowed;

    event Transfer(address indexed _from, address indexed _to, uint256 _value);
    event Approval(address indexed _owner, address indexed _spender, uint256 _value);
    event Deposit(address indexed _owner, uint256 _value);
    event Withdrawal(address indexed _owner, uint256 _value);

    function balanceOf(address _owner) constant returns (uint256 balance) {
        return balances[_owner];
    }

    function transfer(address _to, uint256 _value) returns (bool success) {
        if (balances[msg.sender] < _value) throw;
        if (!safeToAdd(balances[_to], _value)) throw;
        balances[msg.sender] -= _value;
        balances[_to] += _value;
        Transfer(msg.sender, _to, _value);
        return true;
    }

    function transferFrom(address _from, address _to, uint256 _value) returns (bool success) {
        if (balances[_from] < _value) throw;
        if (allowed[_from][msg.sender] < _value) throw;
        if (!safeToAdd(balances[_to], _value)) throw;
        allowed[_from][msg.sender] -= _value;
        balances[_from] -= _value;
        balances[_to] += _value;
        Transfer(_from, _to, _value);
        return true;
    }

    function approve(address _spender, uint256 _value) returns (bool success) {
        allowed[msg.sender][_spender] = _value;
        Approval(msg.sender, _spender, _value);
        return true;
    }

    function allowance(address _owner, address _spender) constant returns (uint256 remaining) {
        return allowed[_owner][_spender];
    }

    function totalSupply() constant returns (uint256 supply) {
        return this.balance;
    }

    function withdraw(uint256 _value) returns (bool success) {
        if (balances[msg.sender] >= _value) {
            if (msg.sender.call.value(_value)()) {
                balances[msg.sender] -= _value;
                Withdrawal(msg.sender, _value);
                return true;
            }
        }
    }

    function deposit() returns (bool success) {
        balances[msg.sender] += msg.value;
        Deposit(msg.sender, msg.value);
        return true;
    }

    function () returns (bool success) {
        return deposit();
    }

    function safeToAdd(uint a, uint b) internal returns (bool) {
        return (a + b >= a);
    }
}