Ballot

// Submitted by EthereumHistory (ethereumhistory.com)
contract Ballot {
    address public chairperson;
    uint8 public numProposals;
    mapping(address => uint) public voterWeight;
    mapping(address => bool) public voted;
    mapping(address => uint8) public votes;
    mapping(address => address) public delegations;
    mapping(uint8 => uint) public voteCounts;

    function Ballot() {
        chairperson = msg.sender;
        numProposals = 5;
    }

    function winningProposal() constant returns (uint8 _winningProposal) {
        uint256 winningVoteCount = 0;
        for (uint8 prop = 0; prop < numProposals; prop++)
            if (voteCounts[prop] > winningVoteCount) {
                winningVoteCount = voteCounts[prop];
                _winningProposal = prop;
            }
    }
    function delegate(address to) {
        address sender = msg.sender;
        if (voted[sender]) return;
        while (delegations[to] != address(0) && delegations[to] != sender)
            to = delegations[to];
        if (to == sender) return;
        voted[sender] = true;
        delegations[sender] = to;
        if (voted[to])
            voteCounts[votes[to]] += voterWeight[sender];
        else
            voterWeight[to] += voterWeight[sender];
    }

    function vote(uint8 toProposal) {
        address sender = msg.sender;
        if (voted[sender] || toProposal >= numProposals) return;
        voted[sender] = true;
        votes[sender] = toProposal;
        voteCounts[toProposal] += voterWeight[sender];
    }

    function giveRightToVote(address voter) {
        if (msg.sender != chairperson || voted[voter]) return;
        voterWeight[voter] = 1;
    }

}