Purchase

// Submitted by EthereumHistory (ethereumhistory.com)
contract Purchase {
    uint public value;
    address public seller;
    address public buyer;
    enum State { Created, Locked, Inactive }
    State public state;

    function Purchase() require(msg.value % 2 == 0) {
        seller = msg.sender;
        value = msg.value / 2;
    }

    modifier require(bool _condition) {
        if (!_condition) throw;
        _
    }

    modifier onlyBuyer() {
        if (msg.sender != buyer) throw;
        _
    }

    modifier onlySeller() {
        if (msg.sender != seller) throw;
        _
    }

    modifier inState(State _state) {
        if (state != _state) throw;
        _
    }

    event Aborted();
    event PurchaseConfirmed();
    event ItemReceived();
    event Refunded();

    function abort()
        onlySeller
        inState(State.Created)
    {
        seller.send(this.balance);
        state = State.Inactive;
        Aborted();
    }

    function confirmPurchase()
        inState(State.Created)
        require(msg.value == 2 * value)
    {
        buyer = msg.sender;
        state = State.Locked;
        PurchaseConfirmed();
    }

    function confirmReceived()
        onlyBuyer
        inState(State.Locked)
    {
        buyer.send(value);
        seller.send(this.balance);
        state = State.Inactive;
        ItemReceived();
    }

    function refund()
        onlySeller
        inState(State.Locked)
    {
        buyer.send(2 * value);
        seller.send(this.balance);
        state = State.Inactive;
        Refunded();
    }

    function() {
        throw;
    }
}